How can I get the name of the currently executing test?

This workaround is only an available option in FlexUnit 4.1 Beta 2 or higher (3 is preferred).For the latest nightly build check out builds.flexunit.org. For point releases, please visit flexunit.org to download.

First create a class named MethodNamRule, it should extend MethodRuleBase and implement IMethodRule.

public class MethodNameRule extends MethodRuleBase implements IMethodRule 
{
...
}

Declare a public var named methodName of type String.

public var methodName:String;

In the new class, you are going to override two public functions. The first is named evaluate:

override public function evaluate( parentToken : AsyncTestToken ):void 
{
    super.evaluate( parentToken );
    proceedToNextStatement();
}

The second function is named apply, this will capture the method name and assign it to the instance variable methodName, then it will just return the super() method.

override public function apply( base : IAsyncStatement, method : FrameworkMethod, test : Object ) : IAsyncStatement 
{
    methodName = method.name;

    return super.apply( base, method, test );
}

Altogether, the new class should read as follows:

public class MethodNameRule extends MethodRuleBase implements IMethodRule 
{
    public var methodName:String;

    override public function evaluate( parentToken : AsyncTestToken ):void {
        super.evaluate( parentToken );
        proceedToNextStatement();
    }

    override public function apply( base : IAsyncStatement, method : FrameworkMethod, test : Object ) : IAsyncStatement {
        methodName = method.name;

        return super.apply( base, method, test );
    }

    public function MethodNameRule() {
        super();
    }
}

This new class should be instantiated within the test cases, and decorated with [Rule] metadata. The instance will make its methodName variable available to any test case, and that variable will contain the name of the test case when it is run. For example:

public class ThisClassCanRetrieveMethodNames
{
    [Rule]
    public var methodNameRule:MethodNameRule = new MethodNameRule();

    [Test]
    public function check():void {
        assertTrue( 2 > 0);
        trace( methodNameRule.methodName );
    }

    [Test]
    public function followUpCheck():void {
        assertTrue( 3 > 0);
        trace( methodNameRule.methodName );
    }
}